Del via

INFO. TABELLER

Gælder for: beregnet kolonne beregnet tabel måling visuel beregning DAX forespørgsel

Returnerer en tabel med oplysninger om hver tabel i den semantiske model med kolonner, der svarer til skemarækkesættet for tabelobjekter (f.eks. navn, beskrivelse og synlighed).

Syntaks

INFO.TABLES ( [<Restriction name>, <Restriction value>], ... )

Parametre

Parametre er valgfrie for denne DAX funktion. Når der bruges parametre, skal begge angives. Mere end ét par parametre er tilladt. Begrænsningsnavnet og -værdien er tekst og indtastet i dobbelte anførselstegn.

Periode Definition
Begrænsningsnavn Navnet på den begrænsning, der bruges til at filtrere resultaterne.
Begrænsningsværdi Værdi, der bruges til at filtrere resultaterne af begrænsningen.

Restriktioner

Normalt kan alle kolonner i resultaterne af DAX-funktionen bruges som en begrænsning. Yderligere begrænsninger kan også være tilladt.

Returværdi

En tabel, hvis kolonner stemmer overens med skemarækkesættet for tabelobjekter i den aktuelle semantiske model.

Column Betegnelse
id Entydigt id for tabellen
Model-id Fremmed nøgle til den model, der indeholder denne tabel
Navn Navnet på tabellen
DataCategory Klassificering af datakategori for tabellen
Betegnelse Beskrivelse af tabellen
ErSkjult Boolesk værdi, der angiver, om tabellen er skjult for klientprogrammer
TableStorageID Fremmed nøgle til oplysningerne om tabellageret
ModifiedTime Dato og klokkeslæt for seneste ændring af tabellen
StructureModifiedTime Dato og klokkeslæt for seneste ændring af tabelstrukturen
Systemflag Systemflag til intern tabeladministration
Vis kunasvariationer Boolesk værdi, der angiver, om tabellen kun skal vise variationer
IsPrivate Boolesk værdi, der angiver, om tabellen er privat
DefaultDetailRowsDefinitionID Fremmed nøgle til standarddefinitionen for detaljerækker
AlternateSourcePrecedence Prioriteret rækkefølge for alternative datakilder
RefreshPolicyID Fremmed nøgle til opdateringspolitikken for trinvis opdatering
CalculationGroupID Fremmed nøgle til beregningsgruppen, hvis denne tabel er en beregningsgruppe
ExcludeFromModelRefresh Boolesk værdi, der angiver, om denne tabel skal udelades fra modelopdatering
Afstamningsmærke Afstamningsmærke til sporing af tabelafstamning
SourceLineageTag Kildeafstamningsmærke fra den oprindelige datakilde
SystemAdministreret Boolesk værdi, der angiver, om tabellen er systemadministrerede

Bemærkninger

  • Nyttig til dokumentations- og styringsscenarier.
  • Tilladelser, der kræves, afhænger af værten. Det kan kræve modeladministratortilladelser at forespørge om komplette metadata.

Eksempel

Følgende DAX forespørgsel kan køres i DAX forespørgselsvisning:

EVALUATE
	INFO.TABLES()

Eksempel 2 – DAX forespørgsel med joinforbindelser

Følgende DAX forespørgsel kan køres i DAX forespørgselsvisning:

EVALUATE
VAR _Tables = 
    SELECTCOLUMNS(
        INFO.TABLES(),
        "TableID", [ID],
        "Table Name", [Name],
        "Description", [Description],
        "Is Hidden", [IsHidden],
        "Calculation Group ID", [CalculationGroupID],
        "Refresh Policy ID", [RefreshPolicyID]
    )

VAR _CalculationGroups = 
    SELECTCOLUMNS(
        INFO.CALCULATIONGROUPS(),
        "CalculationGroupID", [ID],
        "Calculation Group Name", [Name]
    )

VAR _RefreshPolicies = 
    SELECTCOLUMNS(
        INFO.REFRESHPOLICIES(),
        "RefreshPolicyID", [ID],
        "Policy Type", [PolicyType],
        "Incremental Periods", [IncrementalPeriods]
    )

VAR _CombinedTable1 = 
    NATURALLEFTOUTERJOIN(
        _Tables,
        _CalculationGroups
    )

VAR _CombinedTable2 = 
    NATURALLEFTOUTERJOIN(
        _CombinedTable1,
        _RefreshPolicies
    )

RETURN
    SELECTCOLUMNS(
        _CombinedTable2,
        "Table Name", [Table Name],
        "Description", [Description],
        "Is Hidden", [Is Hidden],
        "Calculation Group", [Calculation Group Name],
        "Policy Type", [Policy Type],
        "Incremental Periods", [Incremental Periods]
    )
ORDER BY [Table Name]

Se også

  • Last updated on