Exercise - Add parameters and decorators

As part of the HR application migration, you're creating a Bicep template to deploy Azure resources. In this exercise, you'll create an Azure App Service plan and App Service app. You'll apply decorators to each parameter to ensure that they'll always contain the values you expect.

During the process, you'll do the following tasks:

This exercise uses the Bicep extension for Visual Studio Code. Be sure to install this extension in Visual Studio Code.

Create a Bicep template with parameters

1. Open Visual Studio Code.

2. Create a new file called main.bicep.

3. Save the empty file so that Visual Studio Code loads the Bicep tooling.

   You can either select File > Save As or select Ctrl+S in Windows (⌘+S on macOS). Be sure to remember where you've saved the file. For example, you might want to create a scripts folder to save it in.

4. Add the following content into the file. You'll deploy the template soon. Enter the content yourself instead of copying and pasting so that you can see how the tooling helps you to write your Bicep files.

   param environmentName string = 'dev'
   param solutionName string = 'toyhr${uniqueString(resourceGroup().id)}'
   param appServicePlanInstanceCount int = 1
   param appServicePlanSku object = {
     name: 'F1'
     tier: 'Free'
   }
   param location string = 'eastus'
   
   var appServicePlanName = '${environmentName}-${solutionName}-plan'
   var appServiceAppName = '${environmentName}-${solutionName}-app'
   

   You're creating several parameters here, and they use a mixture of types. You're defining default values for each parameter. Some of the default values include string interpolation and the uniqueString() function.

   Tip

   The uniqueString() function is useful for creating globally unique resource names. It returns a string that's the same on every deployment to the same resource group, but different when you deploy to different resource groups or subscriptions.

   You're also defining variables that construct the names of the Azure App Service plan and App Service app. Their values include some of the parameters you've specified. Parameter values can be overridden by the user who executes the deployment, but the values of the variables can't be overridden.

5. In the main.bicep file in Visual Studio Code, add the following code to the bottom of the file:

   resource appServicePlan 'Microsoft.Web/serverfarms@2024-04-01' = {
     name: appServicePlanName
     location: location
     sku: {
       name: appServicePlanSku.name
       tier: appServicePlanSku.tier
       capacity: appServicePlanInstanceCount
     }
   }
   
   resource appServiceApp 'Microsoft.Web/sites@2024-04-01' = {
     name: appServiceAppName
     location: location
     properties: {
       serverFarmId: appServicePlan.id
       httpsOnly: true
     }
   }
   

   Notice that the resources use the values of the parameters you defined.

6. Save the changes to the file.

Add parameter descriptions

1. In the main.bicep file in Visual Studio Code, add the @description decorator directly above every parameter that you created in the previous task. The parameters should look similar to this example:

   @description('The name of the environment. This must be dev, test, or prod.')
   param environmentName string = 'dev'
   
   @description('The unique name of the solution. This is used to ensure that resource names are unique.')
   param solutionName string = 'toyhr${uniqueString(resourceGroup().id)}'
   
   @description('The number of App Service plan instances.')
   param appServicePlanInstanceCount int = 1
   
   @description('The name and tier of the App Service plan SKU.')
   param appServicePlanSku object = {
     name: 'F1'
     tier: 'Free'
   }
   
   @description('The Azure region into which the resources should be deployed.')
   param location string = 'eastus'
   

2. Save the changes to the file.

Limit input values

Your toy company will deploy the HR application to three environments: dev, test, and prod. You'll limit the environmentName parameter to only allow those three values.

1. In the main.bicep file in Visual Studio Code, find the environmentName parameter. Insert an @allowed decorator underneath its @description decorator. After you're finished, the parameter should look like this example:

   @description('The name of the environment. This must be dev, test, or prod.')
   @allowed([
     'dev'
     'test'
     'prod'
   ])
   param environmentName string = 'dev'
   

   Notice that you're limiting the parameter value for environmentName parameter to only dev, test, and prod. If more environments are added in the future, you'll need to update this list.

2. Save the changes to the file.

Limit input lengths

Your solutionName parameter is used to generate the names of resources. You want to enforce a minimum length of 5 characters and a maximum length of 30 characters.

1. In the main.bicep file in Visual Studio Code, find the solutionName parameter. Add @minLength and @maxLength decorators underneath the @description decorator. After you're finished, the parameter should look like this example:

   @description('The unique name of the solution. This is used to ensure that resource names are unique.')
   @minLength(5)
   @maxLength(30)
   param solutionName string = 'toyhr${uniqueString(resourceGroup().id)}'
   

2. Save the changes to the file.

Limit numeric values

Next, you'll ensure that the appServicePlanInstanceCount parameter only allows values between 1 and 10.

1. In the main.bicep file in Visual Studio Code, find the appServicePlanInstanceCount parameter. Add @minValue and @maxValue decorators underneath the @description decorator. After you're finished, the parameter should look like this example:

   @description('The number of App Service plan instances.')
   @minValue(1)
   @maxValue(10)
   param appServicePlanInstanceCount int = 1
   

2. Save the changes to the file.

Verify your Bicep file

After you've completed all of the preceding changes, your Bicep file should look like this example:

@description('The name of the environment. This must be dev, test, or prod.')
@allowed([
  'dev'
  'test'
  'prod'
])
param environmentName string = 'dev'

@description('The unique name of the solution. This is used to ensure that resource names are unique.')
@minLength(5)
@maxLength(30)
param solutionName string = 'toyhr${uniqueString(resourceGroup().id)}'

@description('The number of App Service plan instances.')
@minValue(1)
@maxValue(10)
param appServicePlanInstanceCount int = 1

@description('The name and tier of the App Service plan SKU.')
param appServicePlanSku object = {
  name: 'F1'
  tier: 'Free'
}

@description('The Azure region into which the resources should be deployed.')
param location string = 'eastus'

var appServicePlanName = '${environmentName}-${solutionName}-plan'
var appServiceAppName = '${environmentName}-${solutionName}-app'

resource appServicePlan 'Microsoft.Web/serverfarms@2024-04-01' = {
  name: appServicePlanName
  location: location
  sku: {
    name: appServicePlanSku.name
    tier: appServicePlanSku.tier
    capacity: appServicePlanInstanceCount
  }
}

resource appServiceApp 'Microsoft.Web/sites@2024-04-01' = {
  name: appServiceAppName
  location: location
  properties: {
    serverFarmId: appServicePlan.id
    httpsOnly: true
  }
}

If it doesn't, either copy the example or adjust your template to match the example.

Deploy the Bicep template to Azure

az bicep install && az bicep upgrade

az deployment group create --name main --template-file main.bicep

New-AzResourceGroupDeployment -Name main -TemplateFile main.bicep

Verify your deployment

1. Go to the Azure portal and make sure you're in the correct subscription.

2. On the left-side panel, select Resource groups.

3. Select your resource group name.

4. In Overview, you can see that one deployment succeeded.

   

5. Select 1 Succeeded to see the details of the deployment.

   

6. Select the deployment called main to see what resources were deployed, and then select Deployment details to expand it. In this case, there's an App Service plan and app.

   

7. On the left menu, select Inputs.

   

8. Notice that the parameters and their values are listed.

   

9. Leave the page open in your browser. You'll check on deployments again later.