How to set text font, size, and color in a macro

Question

How to set text font, size, and color in a macro

Donald Ray 60

I want to set the text font, size, and color of a rectangle named "Loser" into which text will be entered.

The Loser rectangle is on the last slide.

The button to enter the text in Loser is on the first slide 1.

I have added losingTeam = "TEAM1" as an example.

SetLoser enteres "TEAM1" in the losingTeam rectangle, however the text font and size are not Impact 60.

Please advise what I am doing wrong.

Sub SetLoser() 

Dim resultsSlide As Slide

Dim resultsSlideIndex As Integer

Dim losingTeam As String



losingTeam = "TEAM 1"

resultsSlideIndex = ActivePresentation.Slides.count

Set resultsSlide = ActivePresentation.Slides(resultsSlideIndex)

resultsSlide.Shapes("Loser").TextFrame.TextRange.Font.name = Impact

resultsSlide.Shapes("Loser").TextFrame.TextRange.Font.Size = 60

resultsSlide.Shapes("Loser").TextFrame.TextRange.Font.Color.RGB = RGB(255, 192, 0)

resultsSlide.Shapes("Loser").TextFrame.TextRange.Text =losingTeam

End Sub

Mod moved from : Microsoft 365 and Office | PowerPoint | For home | Windows

0 comments

Answer accepted by question author

0 additional answers

Your answer

Answer 1

Use a string for the font name and set the font properties before or after assigning the text; the key issue is that Impact must be quoted.

Change this line:

resultsSlide.Shapes("Loser").TextFrame.TextRange.Font.name = Impact

to:

resultsSlide.Shapes("Loser").TextFrame.TextRange.Font.Name = "Impact"

A cleaned-up version of the macro:

Sub SetLoser()
    Dim resultsSlide As Slide
    Dim resultsSlideIndex As Integer
    Dim losingTeam As String

    losingTeam = "TEAM 1"
    resultsSlideIndex = ActivePresentation.Slides.Count
    Set resultsSlide = ActivePresentation.Slides(resultsSlideIndex)

    With resultsSlide.Shapes("Loser").TextFrame.TextRange
        .Text = losingTeam
        .Font.Name = "Impact"
        .Font.Size = 60
        .Font.Color.RGB = RGB(255, 192, 0)
    End With
End Sub

This sets the text, font name, size, and color for the entire text range of the shape named "Loser" on the last slide.

References:

Share via

How to set text font, size, and color in a macro

0 additional answers

Your answer