Erstellen eines privaten Azure Kubernetes Service (AKS)-Clusters

• Terraform lokal installiert. Installationsanweisungen finden Sie unter Install Terraform.

Erstellen einer Ressourcengruppe

Erstellen Sie mit dem Befehl az group create eine Ressourcengruppe. Sie können auch eine vorhandene Ressourcengruppe für Ihren AKS-Cluster verwenden.

az group create \
    --name <private-cluster-resource-group> \
    --location <location>

Erstellen Sie mit dem Befehl „az aks create“ mit dem --enable-private-cluster-Flag einen privaten Cluster mit Standardnetzwerk.

Schlüsselparameter in diesem Befehl:

• --enable-private-cluster: Aktiviert den privaten Clustermodus.

az aks create \
    --name <private-cluster-name> \
    --resource-group <private-cluster-resource-group> \
    --load-balancer-sku standard \
    --enable-private-cluster \
    --generate-ssh-keys

1. Erstellen Sie eine Datei mit dem Namen main.tf, und fügen Sie den folgenden Code hinzu, um die Terraform-Version zu definieren und den Azure Anbieter anzugeben:

   terraform {
     required_version = ">= 1.3.0"
     required_providers {
       azurerm = {
         source  = "hashicorp/azurerm"
         version = "~> 4.0"
       }
     }
   }
   
   provider "azurerm" {
     features {}
     subscription_id = var.subscription_id
   }
   

2. Fügen Sie den folgenden Code zu main.tf hinzu, um Eingabevariablen für Ihre Azure Abonnement-ID, den Ressourcengruppennamen, den Standort und den AKS-Clusternamen zu erstellen. Sie können die Standardwerte nach Bedarf ändern.

   variable "subscription_id" {
     description = "The Azure subscription ID."
     type = string
   }
   
   variable "resource_group_name" {
     description = "The name of the resource group for the AKS cluster."
     type        = string
     default     = "rg-private-aks-basic"
   }
   
   variable "location" {
     description = "The Azure region where the resources will be created."
     type        = string
     default     = "eastus"
   }
   
   variable "aks_cluster_name" {
     description = "The name of the AKS cluster."
     type        = string
     default     = "aks-private-basic"
   }
   

3. Fügen Sie dem main.tf den folgenden Code hinzu, um eine Azure Ressourcengruppe zu erstellen:

   resource "azurerm_resource_group" "this" {
     name     = var.resource_group_name
     location = var.location
   }
   

4. Fügen Sie den folgenden Code zu main.tf hinzu, um einen privaten AKS-Cluster mit einfacher Netzwerkkonfiguration zu erstellen.

   resource "azurerm_kubernetes_cluster" "this" {
     name                = var.aks_cluster_name
     location            = azurerm_resource_group.this.location
     resource_group_name = azurerm_resource_group.this.name
     dns_prefix          = "privatebasicaks"
   
     private_cluster_enabled = true
   
     default_node_pool {
       name       = "system"
       node_count = 1
       vm_size    = "Standard_DS2_v2"
     }
   
     identity {
       type = "SystemAssigned"
     }
   
     network_profile {
       load_balancer_sku = "standard"
       network_plugin    = "kubenet"
     }
   }
   

5. Führen Sie die Schritte aus, um Terraform zu initialisieren, die Terraform-Konfiguration zu formatieren und zu validieren, einen Terraform-Ausführungsplan zu erstellen, die Terraform-Konfiguration anzuwenden und eine Verbindung mit dem AKS-Cluster herzustellen.

Erstellen Sie einen privaten Cluster mit erweiterten Netzwerken mithilfe des az aks create Befehls.

Schlüsselparameter in diesem Befehl:

• --enable-private-cluster: Aktiviert den privaten Clustermodus.
• --network-plugin azure: Gibt das Azure CNI-Netzwerk-Plug-In an.
• --vnet-subnet-id <subnet-id>: Die Ressourcen-ID eines vorhandenen Subnetzes in einem VNet.
• --dns-service-ip <dns-service-ip>: Eine verfügbare IP-Adresse im Kubernetes-Dienstadressenbereich, die für den Cluster-DNS-Dienst verwendet werden soll. Beispiel: 10.2.0.10.
• --service-cidr <service-cidr>: Ein CIDR-Notations-IP-Bereich, aus dem Dienstcluster-IPs zugewiesen werden sollen. Beispiel: 10.2.0.0/24.

az aks create \
    --resource-group <private-cluster-resource-group> \
    --name <private-cluster-name> \
    --load-balancer-sku standard \
    --enable-private-cluster \
    --network-plugin azure \
    --vnet-subnet-id <subnet-id> \
    --dns-service-ip <dns-service-ip> \
    --service-cidr <service-cidr> \
    --generate-ssh-keys

1. Erstellen Sie eine Datei mit dem Namen main.tf, und fügen Sie den folgenden Code hinzu, um die Terraform-Version zu definieren und den Azure Anbieter anzugeben:

   terraform {
     required_version = ">= 1.3.0"
     required_providers {
       azurerm = {
         source  = "hashicorp/azurerm"
         version = "~> 4.0"
       }
     }
   }
   
   provider "azurerm" {
     features {}
     subscription_id = var.subscription_id
   }
   

2. Fügen Sie den folgenden Code zu main.tf hinzu, um Eingabevariablen für Ihre Azure Abonnement-ID, Ressourcengruppenname, Standort, AKS-Clustername, VNet-Namen (Virtual Network) und Subnetznamen zu erstellen. Sie können die Standardwerte nach Bedarf ändern.

   variable "subscription_id" {
     description = "The Azure subscription ID."
     type = string
   }
   
   variable "resource_group_name" {
     description = "The name of the resource group for the AKS cluster."
     type = string
     default = "rg-private-aks-advanced"
   }
   
   variable "location" {
     description = "The Azure region where the resources will be created."
     type = string
     default = "eastus"
   }
   
   variable "aks_cluster_name" {
     description = "The name of the AKS cluster."
     type = string
     default = "aks-private-advanced"
   }
   
   variable "vnet_name" {
     description = "The name of the virtual network."
     type = string
     default = "vnet-private-aks"
   }
   
   variable "subnet_name" {
     description = "The name of the subnet used by AKS."
     type = string
     default = "snet-aks"
   }
   

3. Fügen Sie den folgenden Code zu main.tf hinzu, um eine Azure Ressourcengruppe, VNet und Subnetz zu erstellen:

   resource "azurerm_resource_group" "this" {
     name = var.resource_group_name
     location = var.location
   }
   
   resource "azurerm_virtual_network" "this" {
     name = var.vnet_name
     location = azurerm_resource_group.this.location
     resource_group_name = azurerm_resource_group.this.name
     address_space = ["10.0.0.0/8"]
   }
   
   resource "azurerm_subnet" "aks" {
     name = var.subnet_name
     resource_group_name  = azurerm_resource_group.this.name
     virtual_network_name = azurerm_virtual_network.this.name
     address_prefixes = ["10.240.0.0/16"]
   }
   

4. Fügen Sie den folgenden Code zu main.tf hinzu, um den AKS-Cluster mit erweiterter Netzwerkkonfiguration zu erstellen.

   resource "azurerm_kubernetes_cluster" "this" {
     name = var.aks_cluster_name
     location = azurerm_resource_group.this.location
     resource_group_name = azurerm_resource_group.this.name
     dns_prefix = "privateadvancedaks"
   
     private_cluster_enabled = true
   
     default_node_pool {
       name = "system"
       node_count = 1
       vm_size = "Standard_DS2_v2"
       vnet_subnet_id = azurerm_subnet.aks.id
     }
   
     identity {
       type = "SystemAssigned"
     }
   
     network_profile {
       load_balancer_sku = "standard"
       network_plugin = "azure"
       dns_service_ip = "10.2.0.10"
       service_cidr = "10.2.0.0/24"
     }
   }
   

5. Führen Sie die Schritte aus, um Terraform zu initialisieren, die Terraform-Konfiguration zu formatieren und zu validieren, einen Terraform-Ausführungsplan zu erstellen, die Terraform-Konfiguration anzuwenden und eine Verbindung mit dem AKS-Cluster herzustellen.

Deaktivieren Sie einen öffentlichen FQDN beim Erstellen eines privaten AKS-Clusters mit dem Befehl az aks create und dem Flag --disable-public-fqdn.

Schlüsselparameter in diesem Befehl:

• --disable-public-fqdn: Deaktiviert den vollqualifizierten öffentlichen Domänennamen (FQDN) für den API-Server.
• --assign-identity <resource-id>: Gibt die verwaltete Identität an, die für den Cluster verwendet werden soll.
• --private-dns-zone [system|none]: Gibt die private DNS-Zone an, die für den Cluster verwendet werden soll. system ist der Standardwert beim Konfigurieren einer privaten DNS-Zone. Wenn Sie weglassen --private-dns-zone, erstellt AKS eine private DNS-Zone in der Knotenressourcengruppe. none deaktiviert die Erstellung einer privaten DNS-Zone.

az aks create \
    --name <private-cluster-name> \
    --resource-group <private-cluster-resource-group> \
    --load-balancer-sku standard \
    --enable-private-cluster \
    --assign-identity <resource-id> \
    --private-dns-zone [system|none] \
    --disable-public-fqdn \
    --generate-ssh-keys

1. Führen Sie die Schritte 1 bis 3 im Erstellen eines privaten AKS-Clusters mit erweiterter Netzwerkkonfiguration oder Erstellen eines privaten AKS-Clusters mit Standard-Netzwerkkonfiguration aus, um die Terraform-Konfiguration einzurichten und die erforderlichen Ressourcen je nach Szenario zu erstellen. In diesem Beispiel werden fortgeschrittene Netzwerke verwendet.

2. Fügen Sie den folgenden Code zu main.tf hinzu, um einen privaten AKS-Cluster mit einer vom Benutzer zugewiesenen Identität zu erstellen und den öffentlichen FQDN zu deaktivieren.

   resource "azurerm_user_assigned_identity" "aks" {
     name = "id-private-aks-public-fqdn-off"
     location = azurerm_resource_group.this.location
     resource_group_name = azurerm_resource_group.this.name
   }
   resource "azurerm_kubernetes_cluster" "this" {
     name = var.aks_cluster_name
     location = azurerm_resource_group.this.location
     resource_group_name = azurerm_resource_group.this.name
     dns_prefix = "privateaks"
     private_cluster_enabled = true
     private_cluster_public_fqdn_enabled = false
   
     private_dns_zone_id = "System"
   
     default_node_pool {
       name = "system"
       node_count = 1
       vm_size = "Standard_DS2_v2"
       vnet_subnet_id = azurerm_subnet.aks.id
     }
     identity {
       type = "UserAssigned"
       identity_ids = [azurerm_user_assigned_identity.aks.id]
     }
     network_profile {
       load_balancer_sku = "standard"
       network_plugin = "azure"
       dns_service_ip = "10.2.0.10"
       service_cidr = "10.2.0.0/24"
     }
   }
   

3. Führen Sie die Schritte aus, um Terraform zu initialisieren, die Terraform-Konfiguration zu formatieren und zu validieren, einen Terraform-Ausführungsplan zu erstellen, die Terraform-Konfiguration anzuwenden und eine Verbindung mit dem AKS-Cluster herzustellen.

Deaktivieren Sie einen öffentlichen FQDN in einem vorhandenen AKS-Cluster mit dem Befehl „az aks update“ mit dem --disable-public-fqdn-Flag.

Schlüsselparameter in diesem Befehl:

• --disable-public-fqdn: Deaktiviert den vollqualifizierten öffentlichen Domänennamen (FQDN) für den API-Server.

az aks update \
    --name <private-cluster-name> \
    --resource-group <private-cluster-resource-group> \
    --disable-public-fqdn

1. Fügen Sie dem vorhandenen main.tf Code den folgenden Code hinzu, um den öffentlichen FQDN für einen vorhandenen AKS-Cluster zu deaktivieren. In diesem Beispiel werden fortgeschrittene Netzwerke verwendet. Sie können sie so ändern, dass sie standardmäßig grundlegende Netzwerke verwendet, indem Sie die relevanten Terraform-Ressourcen und -Parameter ändern.

   resource "azurerm_kubernetes_cluster" "this" {
     name = var.aks_cluster_name
     location = azurerm_resource_group.this.location
     resource_group_name = azurerm_resource_group.this.name
     dns_prefix = "privateaks"
   
     private_cluster_enabled = true
     private_cluster_public_fqdn_enabled = false
     private_dns_zone_id = "System"
   
     default_node_pool {
       name = "system"
       node_count = 1
       vm_size = "Standard_DS2_v2"
       vnet_subnet_id = azurerm_subnet.aks.id
     }
   
     identity {
       type = "UserAssigned"
       identity_ids = [azurerm_user_assigned_identity.aks.id]
     }
   
     network_profile {
       load_balancer_sku = "standard"
       network_plugin = "azure"
       dns_service_ip = "10.2.0.10"
       service_cidr = "10.2.0.0/24"
     }
   }
   

2. Wenden Sie die aktualisierte Terraform-Konfiguration mit den Befehlen terraform plan und terraform apply an.

   terraform plan
   terraform apply
   

Konfigurationsoptionen für privates DNS

Sie können private DNS-Einstellungen für einen privaten AKS-Cluster mithilfe des Azure CLI (mit dem parameter --private-dns-zone) oder einer AZURE RESOURCE MANAGER-Vorlage (mit der Eigenschaft privateDNSZone) konfigurieren. In der folgenden Tabelle sind die Optionen aufgeführt, die für den --private-dns-zone Parameter oder die privateDNSZone Eigenschaft verfügbar sind.

Überlegungen zu privatem DNS

Beachten Sie beim Konfigurieren von privatem DNS für einen privaten AKS-Cluster die folgenden Überlegungen:

• Wenn sich die private DNS-Zone in einem anderen Abonnement als der AKS-Cluster befindet, müssen Sie den Microsoft.ContainerService Azure-Anbieter in beiden Abonnements registrieren.
• Wenn Ihr AKS-Cluster mit einem Active Directory Dienstprinzipal konfiguriert ist, unterstützt AKS nicht die Verwendung einer vom System zugewiesenen verwalteten Identität mit benutzerdefinierter privater DNS-Zone. Der Cluster muss die vom Benutzer zugewiesene verwaltete Identitätsauthentifizierung verwenden.

Erstellen Sie einen privaten AKS-Cluster mit einer privaten DNS-Zone mithilfe des az aks create Befehls.

Schlüsselparameter in diesem Befehl:

• --enable-private-cluster: Aktiviert den privaten Clustermodus.
• --private-dns-zone [system|none]: Konfiguriert die private DNS-Zone für den Cluster. system ist der Standardwert beim Konfigurieren einer privaten DNS-Zone. Wenn Sie weglassen --private-dns-zone, erstellt AKS eine private DNS-Zone in der Knotenressourcengruppe. none deaktiviert die Erstellung einer privaten DNS-Zone.
• --assign-identity <resource-id>: Die Ressourcen-ID einer vom Benutzer zugewiesenen verwalteten Identität mit den Rollen Privates DNS Zone Contributor und Network Contributor.

az aks create \
    --name <private-cluster-name> \
    --resource-group <private-cluster-resource-group> \
    --load-balancer-sku standard \
    --enable-private-cluster \
    --assign-identity <resource-id> \
    --private-dns-zone [system|none] \
    --generate-ssh-keys

1. Führen Sie die Schritte 1 bis 3 im Erstellen eines privaten AKS-Clusters mit erweiterter Netzwerkkonfiguration oder Erstellen eines privaten AKS-Clusters mit Standard-Netzwerkkonfiguration aus, um die Terraform-Konfiguration einzurichten und die erforderlichen Ressourcen je nach Szenario zu erstellen. In diesem Beispiel werden fortgeschrittene Netzwerke verwendet.

2. Fügen Sie den folgenden Code hinzu, um einen privaten AKS-Cluster mit einer AKS-verwalteten privaten DNS-Zone zu main.tf erstellen:

   resource "azurerm_kubernetes_cluster" "this" {
    name                = var.aks_cluster_name
    location            = azurerm_resource_group.this.location
    resource_group_name = azurerm_resource_group.this.name
    dns_prefix          = "aks-system-dns"
    private_cluster_enabled = true
    private_dns_zone_id     = "System"
    default_node_pool {
      name           = "system"
      node_count     = 1
      vm_size        = "Standard_DS2_v2"
      vnet_subnet_id = azurerm_subnet.aks.id
    }
    identity {
      type = "SystemAssigned"
    }
    network_profile {
      network_plugin    = "azure"
      load_balancer_sku = "standard"
      dns_service_ip    = "10.2.0.10"
      service_cidr      = "10.2.0.0/24"
    }
   }
   

3. Führen Sie die Schritte aus, um Terraform zu initialisieren, die Terraform-Konfiguration zu formatieren und zu validieren, einen Terraform-Ausführungsplan zu erstellen, die Terraform-Konfiguration anzuwenden und eine Verbindung mit dem AKS-Cluster herzustellen.

Erstellen eines privaten AKS-Clusters ohne private DNS-Zone

1. Führen Sie die Schritte 1 bis 3 im Erstellen eines privaten AKS-Clusters mit erweiterter Netzwerkkonfiguration oder Erstellen eines privaten AKS-Clusters mit Standard-Netzwerkkonfiguration aus, um die Terraform-Konfiguration einzurichten und die erforderlichen Ressourcen je nach Szenario zu erstellen. In diesem Beispiel werden fortgeschrittene Netzwerke verwendet.

2. Fügen Sie den folgenden Code zu main.tf hinzu, um den AKS-Cluster ohne private DNS-Zone zu erstellen.

   resource "azurerm_kubernetes_cluster" "this" {
    name                = var.aks_cluster_name
    location            = azurerm_resource_group.this.location
    resource_group_name = azurerm_resource_group.this.name
    dns_prefix          = "aks-no-dns"
    private_cluster_enabled = true
    private_dns_zone_id     = "None"
    default_node_pool {
      name           = "system"
      node_count     = 1
      vm_size        = "Standard_DS2_v2"
      vnet_subnet_id = azurerm_subnet.aks.id
    }
    identity {
      type = "SystemAssigned"
    }
    network_profile {
      network_plugin    = "azure"
      load_balancer_sku = "standard"
      dns_service_ip    = "10.2.0.10"
      service_cidr      = "10.2.0.0/24"
    }
   }
   

3. Führen Sie die Schritte aus, um Terraform zu initialisieren, die Terraform-Konfiguration zu formatieren und zu validieren, einen Terraform-Ausführungsplan zu erstellen, die Terraform-Konfiguration anzuwenden und eine Verbindung mit dem AKS-Cluster herzustellen.

Erstellen Sie einen privaten AKS-Cluster mit einer benutzerdefinierten privaten DNS-Zone oder Unterzone mithilfe des az aks create Befehls.

Schlüsselparameter in diesem Befehl:

• --enable-private-cluster: Aktiviert den privaten Clustermodus.
• --private-dns-zone [<custom-private-dns-zone-resource-id>|<custom-private-dns-subzone-resource-id>]: Die Ressourcen-ID einer vorhandenen privaten DNS-Zone oder -Unterzone im folgenden Format für Azure globale Cloud: privatelink.<region>.azmk8s.io oder <subzone>.privatelink.<region>.azmk8s.io.
• --assign-identity <resource-id>: Die Ressourcen-ID einer vom Benutzer zugewiesenen verwalteten Identität mit den Rollen Privates DNS Zone Contributor und Network Contributor.

az aks create \
    --name <private-cluster-name> \
    --resource-group <private-cluster-resource-group> \
    --load-balancer-sku standard \
    --enable-private-cluster \
    --assign-identity <resource-id> \
    --private-dns-zone [<custom-private-dns-zone-resource-id>|<custom-private-dns-subzone-resource-id>] \
    --generate-ssh-keys

Wenn Sie eine benutzerdefinierte private DNS-Zone verwenden, sind Sie dafür verantwortlich, die DNS-Infrastruktur zu erstellen und zu verwalten, anstatt sich auf Azure verwalteten DNS zu verlassen. Dazu gehört das Erstellen der DNS-Zone, das Verknüpfen mit Ihrem VNet und das Zuweisen der erforderlichen Berechtigungen für AKS zum Verwalten von Datensätzen.

Für benutzerdefinierte DNS-Konfigurationen müssen Sie eine vom Benutzer zugewiesene Managed Identity mit den Rollen Privates DNS Zone Contributor und Netzwerkmitwirkender verwenden.

1. Führen Sie die Schritte 1 bis 3 im Erstellen eines privaten AKS-Clusters mit erweiterter Netzwerkkonfiguration oder Erstellen eines privaten AKS-Clusters mit Standard-Netzwerkkonfiguration aus, um die Terraform-Konfiguration einzurichten und die erforderlichen Ressourcen je nach Szenario zu erstellen. In diesem Beispiel werden fortgeschrittene Netzwerke verwendet.

2. Fügen Sie den Code hinzu, um einen privaten AKS-Cluster mit einer benutzerdefinierten privaten DNS-Zone oder -Unterzone zu main.tf erstellen:

   resource "azurerm_user_assigned_identity" "aks" {
    name                = "aks-custom-dns-id"
    location            = azurerm_resource_group.this.location
    resource_group_name = azurerm_resource_group.this.name
   }
   resource "azurerm_private_dns_zone" "aks" {
    name                = "privatelink.eastus.azmk8s.io"
    resource_group_name = azurerm_resource_group.this.name
   }
   resource "azurerm_private_dns_zone_virtual_network_link" "link" {
    name                  = "aks-dns-link"
    resource_group_name   = azurerm_resource_group.this.name
    private_dns_zone_name = azurerm_private_dns_zone.aks.name
    virtual_network_id    = azurerm_virtual_network.this.id
   }
   resource "azurerm_role_assignment" "dns" {
    scope                = azurerm_private_dns_zone.aks.id
    role_definition_name = "Private DNS Zone Contributor"
    principal_id         = azurerm_user_assigned_identity.aks.principal_id
   }
   resource "azurerm_role_assignment" "network" {
    scope                = azurerm_virtual_network.this.id
    role_definition_name = "Network Contributor"
    principal_id         = azurerm_user_assigned_identity.aks.principal_id
   }
   resource "azurerm_kubernetes_cluster" "this" {
    name                = var.aks_cluster_name
    location            = azurerm_resource_group.this.location
    resource_group_name = azurerm_resource_group.this.name
    dns_prefix          = "aks-custom-dns"
    private_cluster_enabled = true
    private_dns_zone_id     = azurerm_private_dns_zone.aks.id
    default_node_pool {
      name           = "system"
      node_count     = 1
      vm_size        = "Standard_DS2_v2"
      vnet_subnet_id = azurerm_subnet.aks.id
    }
    identity {
      type         = "UserAssigned"
      identity_ids = [azurerm_user_assigned_identity.aks.id]
    }
    network_profile {
      network_plugin    = "azure"
      load_balancer_sku = "standard"
      dns_service_ip    = "10.2.0.10"
      service_cidr      = "10.2.0.0/24"
    }
    depends_on = [
      azurerm_role_assignment.dns,
      azurerm_role_assignment.network
    ]
   }
   

3. Führen Sie die Schritte aus, um Terraform zu initialisieren, die Terraform-Konfiguration zu formatieren und zu validieren, einen Terraform-Ausführungsplan zu erstellen, die Terraform-Konfiguration anzuwenden und eine Verbindung mit dem AKS-Cluster herzustellen.

Erstellen Sie einen privaten AKS-Cluster mit einer benutzerdefinierten privaten DNS-Zone und Unterdomäne mithilfe des az aks create Befehls.

Schlüsselparameter in diesem Befehl:

• --enable-private-cluster: Aktiviert den privaten Clustermodus.
• --private-dns-zone <custom-private-dns-zone-resource-id>: Die Ressourcen-ID einer vorhandenen privaten DNS-Zone im folgenden Format für Azure globale Cloud: privatelink.<region>.azmk8s.io.
• --fqdn-subdomain <subdomain>: Die Unterdomäne, die für den Cluster-FQDN innerhalb der benutzerdefinierten privaten DNS-Zone verwendet werden soll.
• --assign-identity <resource-id>: Die Ressourcen-ID einer vom Benutzer zugewiesenen verwalteten Identität mit den Rollen Privates DNS Zone Contributor und Network Contributor.

az aks create \
    --name <private-cluster-name> \
    --resource-group <private-cluster-resource-group> \
    --load-balancer-sku standard \
    --enable-private-cluster \
    --assign-identity <resource-id> \
    --private-dns-zone <custom-private-dns-zone-resource-id> \
    --fqdn-subdomain <subdomain> \
    --generate-ssh-keys

1. Führen Sie die Schritte 1 bis 3 im Erstellen eines privaten AKS-Clusters mit erweiterter Netzwerkkonfiguration oder Erstellen eines privaten AKS-Clusters mit Standard-Netzwerkkonfiguration aus, um die Terraform-Konfiguration einzurichten und die erforderlichen Ressourcen je nach Szenario zu erstellen. In diesem Beispiel werden fortgeschrittene Netzwerke verwendet.

2. Fügen Sie den folgenden Code hinzu, um einen privaten AKS-Cluster mit einer benutzerdefinierten privaten DNS-Zone und Unterdomäne zu main.tf erstellen:

   resource "azurerm_kubernetes_cluster" "this" {
    name                = var.aks_cluster_name
    location            = azurerm_resource_group.this.location
    resource_group_name = azurerm_resource_group.this.name
    dns_prefix          = "aks-subdomain"
    private_cluster_enabled = true
    private_dns_zone_id     = azurerm_private_dns_zone.aks.id
    fqdn_subdomain          = "team1"
    default_node_pool {
      name           = "system"
      node_count     = 1
      vm_size        = "Standard_DS2_v2"
      vnet_subnet_id = azurerm_subnet.aks.id
    }
    identity {
      type         = "UserAssigned"
      identity_ids = [azurerm_user_assigned_identity.aks.id]
    }
    network_profile {
      network_plugin    = "azure"
      load_balancer_sku = "standard"
      dns_service_ip    = "10.2.0.10"
      service_cidr      = "10.2.0.0/24"
    }
   }
   

3. Führen Sie die Schritte aus, um Terraform zu initialisieren, die Terraform-Konfiguration zu formatieren und zu validieren, einen Terraform-Ausführungsplan zu erstellen, die Terraform-Konfiguration anzuwenden und eine Verbindung mit dem AKS-Cluster herzustellen.

Sie können nur von byo (Bring Your Own) oder system auf none aktualisieren. Es wird keine andere Kombination von Updatewerten unterstützt.

Aktualisieren Sie einen privaten Cluster von byo oder system auf none, indem Sie den az aks update-Befehl verwenden und den --private-dns-zone-Parameter auf none festlegen.

az aks update \
    --name <private-cluster-name> \
    --resource-group <private-cluster-resource-group> \
    --private-dns-zone none

1. Fügen Sie dem vorhandenen main.tf Code den folgenden Code hinzu, um den privaten AKS-Cluster von einer privaten DNS-Zone auf öffentlich zu aktualisieren. In diesem Beispiel werden fortgeschrittene Netzwerke verwendet. Sie können sie so ändern, dass sie standardmäßig grundlegende Netzwerke verwendet, indem Sie die relevanten Terraform-Ressourcen und -Parameter ändern.

   resource "azurerm_kubernetes_cluster" "this" {
    name                = var.aks_cluster_name
    location            = azurerm_resource_group.this.location
    resource_group_name = azurerm_resource_group.this.name
    dns_prefix          = "aks-update"
    private_cluster_enabled = true
    private_dns_zone_id     = "None"
    default_node_pool {
      name           = "system"
      node_count     = 1
      vm_size        = "Standard_DS2_v2"
      vnet_subnet_id = azurerm_subnet.aks.id
    }
    identity {
      type         = "UserAssigned"
      identity_ids = [azurerm_user_assigned_identity.aks.id]
    }
    network_profile {
      network_plugin    = "azure"
      load_balancer_sku = "standard"
      dns_service_ip    = "10.2.0.10"
      service_cidr      = "10.2.0.0/24"
    }
   }
   

2. Wenden Sie die aktualisierte Terraform-Konfiguration mit den Befehlen terraform plan und terraform apply an.

   terraform plan
   terraform apply
   

Initialisieren Sie Terraform

Initialisieren Sie Terraform im Verzeichnis, das Ihre main.tf Datei enthält, mithilfe des terraform init Befehls. Dieser Befehl lädt den Azure Anbieter herunter, der zum Verwalten von Azure Ressourcen mit Terraform erforderlich ist.

terraform init

Formatieren und Überprüfen der Terraform-Konfiguration

Formatieren Sie und validieren Sie die Terraform-Konfiguration mit den terraform fmt und terraform validate Befehle.

terraform fmt
terraform validate

Terraform-Ausführungsplan erstellen

Erstellen Sie mit dem Befehl „terraform plan“ einen Terraform-Ausführungsplan. Dieser Befehl zeigt Ihnen die Ressourcen, die Terraform in Ihrem Azure-Abonnement erstellen oder ändern wird.

terraform plan -var="subscription_id=<your-subscription-id>"

Terraform-Konfiguration anwenden

Wenden Sie nach der Überprüfung und Bestätigung des Ausführungsplans die Terraform-Konfiguration mit dem terraform apply Befehl an. Mit diesem Befehl werden die in Ihrer main.tf Datei definierten Ressourcen in Ihrem Azure-Abonnement erstellt oder geändert.

terraform apply -var="subscription_id=<your-subscription-id>"