Planen und Steuern von Upgrades für Ihren Azure Kubernetes Service Cluster mithilfe geplanter Wartung

• Es wird vorausgesetzt, dass Sie über ein AKS-Cluster verfügen. Wenn Sie keinen AKS-Cluster haben, lesen Sie Erstellen eines AKS-Clusters.

• Ein aktives Azure-Abonnement. Wenn Sie kein Azure-Abonnement haben, erstellen Sie ein free-Konto, bevor Sie beginnen.

• Legen Sie ihren Abonnementkontext mithilfe des az account set Befehls fest. Beispiel:

  az account set --subscription "00000000-0000-0000-0000-000000000000"
  

• Terraform lokal installiert. Installationsanweisungen finden Sie unter Install Terraform.

Erstellen der Terraform-Konfigurationsdatei

Terraform-Konfigurationsdateien definieren die Infrastruktur, die Terraform erstellt und verwaltet.

Erstellen Sie eine Datei mit dem Namen main.tf, und fügen Sie den folgenden Code hinzu, um die Terraform-Version zu definieren und den Azure Anbieter anzugeben:

terraform {
 required_providers {
   azurerm = {
     source  = "hashicorp/azurerm"
     version = "~>4.0"
   }
   azapi = {
     source  = "azure/azapi"
     version = "~>2.0"
   }
 }
}
provider "azurerm" {
 features {}
}
provider "azapi" {}

Erstellen einer Ressourcengruppe

Fügen Sie dem main.tf den folgenden Code hinzu, um eine Azure Ressourcengruppe zu erstellen. Aktualisieren Sie die location und name Werte, sodass sie Ihrer Umgebung entsprechen.

resource "azurerm_resource_group" "rg" {
 name     = "aks-maintenance-rg"
 location = "East US"
}

Erstellen eines AKS-Clusters

Fügen Sie den folgenden Code hinzu, um einen AKS-Cluster zu main.tf erstellen. Aktualisieren Sie alle Werte nach Bedarf, um ihrer Umgebung zu entsprechen.

resource "azurerm_kubernetes_cluster" "aks" {
 name                = "aks-maintenance-cluster"
 location            = azurerm_resource_group.rg.location
 resource_group_name = azurerm_resource_group.rg.name
 dns_prefix          = "aksmaintenance"
 default_node_pool {
   name       = "nodepool1"
   node_count = 1
   vm_size    = "Standard_DS2_v2"
 }
 identity {
   type = "SystemAssigned"
 }
}

Fügen Sie mithilfe des az aks maintenanceconfiguration add Befehls eine Wartungsfensterkonfiguration zu einem AKS-Cluster hinzu.

Im ersten Beispiel wird eine neue default Konfiguration hinzugefügt, die die Wartung von 1:00 bis 1:00 Uhr jeden Montag in der UTC Zeitzone plant. Das zweite Beispiel fügt eine neue aksManagedAutoUpgradeSchedule-Konfiguration hinzu, mit der die Wartung jeden dritten Freitag zwischen Mitternacht (00:00) und 08:00 Uhr Morgens in der Zeitzone UTC+5:30 geplant wird.

# Add a new default configuration
az aks maintenanceconfiguration add --resource-group $RESOURCE_GROUP --cluster-name $CLUSTER_NAME --name default --schedule-type Weekly --day-of-week Monday --interval-weeks 1 --duration 4 --utc-offset +00:00 --start-time 01:00

# Add a new aksManagedAutoUpgradeSchedule configuration
az aks maintenanceconfiguration add --resource-group $RESOURCE_GROUP --cluster-name $CLUSTER_NAME --name aksManagedAutoUpgradeSchedule --schedule-type Weekly --day-of-week Friday --interval-weeks 3 --duration 8 --utc-offset +05:30 --start-time 00:00

1. Wechseln Sie im Azure-Portal zu Ihrer AKS-Clusterressource.

2. Wählen Sie im Dienstmenü unter "Einstellungen" die Option "Upgrades" aus.

3. Wählen Sie unter Upgrade>Zeitplan für automatische Upgrades die Option Zeitplan hinzufügen aus.

   

4. Konfigurieren Sie im Bereich Wartungszeitplan hinzufügen die folgenden Wartungsfenstereinstellungen:

   • Wiederholungen: Wählen Sie die Häufigkeit für das Wartungsfenster aus. Es wird empfohlen Wöchentlich zu verwenden.
   • Häufigkeit: Wählen Sie den Wochentag für das Wartungsfenster aus. Es wird empfohlen Sonntag zu verwenden.
   • Wartungsstartdatum: Wählen Sie das Startdatum für das Wartungsfenster aus.
   • Wartungsstartzeit: Wählen Sie die Startzeit für das Wartungsfenster aus.
   • UTC-Abweichung: Wählen Sie die UTC-Abweichung für das Wartungsfenster aus. Der Standardwert ist +00:00.

   

5. Wählen Sie Speichern aus.

Anstelle von Parametern könne Sie eine JSON-Datei zum Erstellen einer Wartungskonfiguration verwenden. Wenn Sie diese Methode verwenden, können Sie die Wartung während eines bestimmten Datumsbereichs unterbinden, indem Sie für notAllowedDates, default und aksManagedAutoUpgradeSchedule Konfigurationen angeben aksManagedNodeOSUpgradeSchedule.

1. Erstellen Sie eine JSON-Datei mit den Wartungsfenstereinstellungen.

   Im folgenden Beispiel wird eine default.json Datei erstellt, in der die Wartung jeden Dienstag von 1:00 bis 5:00 Uhr in der UTC Zeitzone geplant ist. Es gibt auch eine Ausnahme zwischen 2021-05-26 und 2021-05-30, wo die Wartung nicht zulässig ist, auch wenn sie sich mit einem Wartungsfenster überschneidet.

   {
     "properties": {
       "maintenanceWindow": {
           "schedule": {
               "weekly": {
                   "intervalWeeks": 1,
                   "dayOfWeek": "Tuesday"
               }
           },
           "durationHours": 4,
           "utcOffset": "+00:00",
           "startTime": "01:00",
           "notAllowedDates": [
               {
                   "start": "2021-05-26",
                   "end": "2021-05-30"
               }
           ]
       }
     }
   }
   

   Im folgenden Beispiel wird eine Datei autoUpgradeWindow.json erstellt, mit der die Wartung alle drei Monate am ersten Tag des Monats zwischen 09:00 und 13:00 Uhr in der Zeitzone UTC-08 geplant wird. Es gibt auch eine Ausnahme zwischen 2023-12-23 und 2024-01-05, wo die Wartung nicht zulässig ist, auch wenn sie sich mit einem Wartungsfenster überschneidet.

   {
     "properties": {
       "maintenanceWindow": {
           "schedule": {
               "absoluteMonthly": {
                   "intervalMonths": 3,
                   "dayOfMonth": 1
               }
           },
           "durationHours": 4,
           "utcOffset": "-08:00",
           "startTime": "09:00",
           "notAllowedDates": [
               {
                   "start": "2023-12-23",
                   "end": "2024-01-05"
               }
           ]
       }
     }
   }
   

2. Fügen Sie die Wartungsfensterkonfiguration mithilfe des az aks maintenanceconfiguration add Befehls mit dem --config-file Parameter hinzu.

   Das erste Beispiel fügt mithilfe der Datei default eine neue default.json-Konfiguration hinzu. Das zweite Beispiel fügt mithilfe der Datei aksManagedAutoUpgradeSchedule eine neue autoUpgradeWindow.json-Konfiguration hinzu.

   # Add a new default configuration
   az aks maintenanceconfiguration add --resource-group $RESOURCE_GROUP --cluster-name $CLUSTER_NAME --name default --config-file ./default.json
   
   # Add a new aksManagedAutoUpgradeSchedule configuration
   az aks maintenanceconfiguration add --resource-group $RESOURCE_GROUP --cluster-name $CLUSTER_NAME --name aksManagedAutoUpgradeSchedule --config-file ./autoUpgradeWindow.json
   

Fügen Sie die Wartungsfensterkonfiguration zu main.tf mithilfe der azapi_resource Ressource hinzu.

Standardwartungskonfiguration

Im folgenden Beispiel wird eine default Wartungskonfiguration erstellt, die die Wartung von 2:00 bis 6:00 Uhr jeden Samstag in der UTC-04:00 Zeitzone plant:

resource "azapi_resource" "default_maintenance" {
 type      = "Microsoft.ContainerService/managedClusters/maintenanceConfigurations@2025-10-01"
 name      = "default"
 parent_id = azurerm_kubernetes_cluster.aks.id
 schema_validation_enabled = false
 body = {
   properties = {
     maintenanceWindow = {
       schedule = {
         weekly = {
           dayOfWeek     = "Saturday"
           intervalWeeks = 1
         }
       }
       durationHours = 4
       startTime     = "02:00"
       utcOffset     = "-04:00"
     }
   }
 }
}

Autoupgrade-Wartungskonfiguration

Im folgenden Beispiel wird eine aksManagedAutoUpgradeSchedule Wartungskonfiguration erstellt, mit der die Wartung jeden Sonntag von 1:00 bis 17:00 Uhr in der UTC-04:00 Zeitzone geplant wird, beginnend am 20. April 2026:

resource "azapi_resource" "auto_upgrade" {
 type      = "Microsoft.ContainerService/managedClusters/maintenanceConfigurations@2025-10-01"
 name      = "aksManagedAutoUpgradeSchedule"
 parent_id = azurerm_kubernetes_cluster.aks.id
 schema_validation_enabled = false
 body = {
   properties = {
     maintenanceWindow = {
       startDate     = "2026-04-20"
       startTime     = "01:00"
       durationHours = 4
       utcOffset     = "-04:00"
       schedule = {
         weekly = {
           dayOfWeek     = "Sunday"
           intervalWeeks = 1
         }
       }
     }
   }
 }
}

Konfiguration der Wartung für das Upgrade des Knoten-Betriebssystems

Im folgenden Beispiel wird eine aksManagedNodeOSUpgradeSchedule Wartungskonfiguration erstellt, die die Ausführung von Montag von 3:00 bis 7:00 Uhr in der UTC-04:00 Zeitzone plant, beginnend am 21. April 2026:

resource "azapi_resource" "node_os_upgrade" {
 type      = "Microsoft.ContainerService/managedClusters/maintenanceConfigurations@2025-10-01"
 name      = "aksManagedNodeOSUpgradeSchedule"
 parent_id = azurerm_kubernetes_cluster.aks.id
 schema_validation_enabled = false
 body = {
   properties = {
     maintenanceWindow = {
       startDate     = "2026-04-21"
       startTime     = "03:00"
       durationHours = 4
       utcOffset     = "-04:00"
       schedule = {
         weekly = {
           dayOfWeek     = "Monday"
           intervalWeeks = 1
         }
       }
     }
   }
 }
}

Aktualisieren Sie eine vorhandene Wartungskonfiguration mithilfe des az aks maintenanceconfiguration update Befehls.

Im folgenden Beispiel wird die Konfiguration aktualisiert, um die default Wartung von 2:00 bis 06:00 Uhr jeden Freitag zu planen:

az aks maintenanceconfiguration update --resource-group $RESOURCE_GROUP --cluster-name $CLUSTER_NAME --name default --schedule-type Weekly --day-of-week Friday --interval-weeks 1 --duration 4 --utc-offset +00:00 --start-time 02:00

1. Navigieren Sie im Azure-Portal zu Ihrer AKS-Clusterressource.

2. Wählen Sie im Dienstmenü unter "Einstellungen" die Option "Upgrades" aus.

3. Wählen Sie unter Upgrade>Zeitplan für automatische Upgrades die Option Zeitplan bearbeiten aus.

   

4. Aktualisieren Sie im Bereich Wartungszeitplan bearbeiten die Wartungsfenstereinstellungen nach Bedarf.

5. Wählen Sie Speichern aus.

1. Aktualisieren Sie die JSON-Konfigurationsdatei mit den neuen Wartungsfenstereinstellungen.

   Im folgenden Beispiel wird die default.json-Datei aus dem vorherigen Abschnitt aktualisiert, um die Wartungsarbeiten jeden Montag von 02:00 bis 06:00 Uhr zu planen.

   {
     "properties": {
       "maintenanceWindow": {
           "schedule": {
               "weekly": {
                   "intervalWeeks": 1,
                   "dayOfWeek": "Monday"
               }
           },
           "durationHours": 4,
           "utcOffset": "+00:00",
           "startTime": "02:00",
           "notAllowedDates": [
               {
                   "start": "2021-05-26",
                   "end": "2021-05-30"
               }
           ]
       }
     }
   }
   

2. Aktualisieren Sie die Konfiguration des Wartungsfensters mit dem az aks maintenanceconfiguration update-Befehl mit dem Parameter --config-file:

   az aks maintenanceconfiguration update --resource-group $RESOURCE_GROUP --cluster-name $CLUSTER_NAME --name default --config-file ./default.json
   

Wenn Sie bereits über einen von Terraform verwalteten AKS-Cluster verfügen, können Sie die Konfiguration des Wartungsfensters aktualisieren, indem Sie die Terraform-Konfigurationsdatei ändern und die Änderungen mithilfe des terraform apply Befehls anwenden.

Initialisieren Sie Terraform

Initialisieren Sie Terraform im Verzeichnis, das Ihre main.tf Datei enthält, mithilfe des terraform init Befehls. Dieser Befehl lädt den Azure Anbieter herunter, der zum Verwalten von Azure Ressourcen mit Terraform erforderlich ist.

terraform init

Terraform-Ausführungsplan erstellen

Erstellen Sie mit dem Befehl „terraform plan“ einen Terraform-Ausführungsplan. Dieser Befehl zeigt Ihnen die Ressourcen, die Terraform in Ihrem Azure-Abonnement erstellen oder ändern wird.

terraform plan

Terraform-Konfiguration anwenden

Wenden Sie nach der Überprüfung und Bestätigung des Ausführungsplans die Terraform-Konfiguration mit dem terraform apply Befehl an. Dieser Befehl erstellt oder ändert die ressourcen, die in Ihrer main.tf-Datei in Ihrem Azure-Abonnement definiert sind.

terraform apply

Löschen Sie mithilfe des az aks maintenanceconfiguration delete Befehls ein Wartungskonfigurationsfenster in Ihrem AKS-Cluster.

Das folgende Beispiel löscht die Wartungskonfiguration autoUpgradeSchedule:

az aks maintenanceconfiguration delete --resource-group $RESOURCE_GROUP --cluster-name $CLUSTER_NAME --name autoUpgradeSchedule

1. Navigieren Sie im Azure-Portal zu Ihrer AKS-Clusterressource.

2. Wählen Sie im Dienstmenü unter Einstellungen die Option Clusterkonfiguration aus.

3. Wählen Sie unter Upgrade>Zeitplan für automatische Upgrades die Option Zeitplan bearbeiten aus.

   

4. Wählen Sie im Bereich Wartungszeitplan bearbeiten die Option Zeitplan entfernen aus.

   

Löschen Sie mithilfe des az aks maintenanceconfiguration delete Befehls ein Wartungskonfigurationsfenster in Ihrem AKS-Cluster.

Das folgende Beispiel löscht die Wartungskonfiguration autoUpgradeSchedule:

az aks maintenanceconfiguration delete --resource-group $RESOURCE_GROUP --cluster-name $CLUSTER_NAME --name autoUpgradeSchedule

Um eine Wartungskonfiguration zu löschen, entfernen Sie den entsprechenden Block aus Ihrer Terraform-Konfiguration, und wenden Sie die Änderungen mithilfe des terraform apply Befehls an.